##################################################################################
#_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/３点バースト_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/#
##################################################################################
#準備は、ホルスターから抜き出す感じで
#発砲は、三点射を三回繰り返す。

#オプション 画像(デフォルトは汎用のマシンガン) 効果音 ユニットＩＤ

戦闘アニメ_３点バースト準備:
戦闘アニメ_スタイリッシュ構え準備:

Local i j

Local UID = _GetName(対象ユニットＩＤ,_GetIDFromArgs())
_CenteringCheck UID

Local U_X = WX(UID)
Local U_Y = WY(UID)
Local C_X C_Y C_X2 C_Y2
Local WP_FILE = _SelectWPBN(マシンガン)
Local G_S = _SelectWPBS(マシンガン)
Local ANG = _GetAngle(UID)
Local X_F = _GetCircumference(ANG,Ｘ)
Local Y_F = _GetCircumference(ANG,Ｙ)
Local X_F2 = _GetCircumference((ANG + 90),Ｘ)
Local Y_F2 = _GetCircumference((ANG + 90),Ｙ)
Local DRCT = _FlipVertical(ANG)
Local T_COL_F = _ColorTime(_IsLight())
Local L_N
Local W_FLG = _IsDoubleWeapon()

If (W_FLG = 0) Then
  Set C_X (U_X + (16 - (G_S \ 2)))
  Set C_Y (U_Y + (16 - (G_S \ 2)))
Else

  If (DRCT = "上下反転")  Then
    Set C_X (U_X + 16 + (6 * X_F) - (6 * X_F2) - (G_S \ 2))
    Set C_Y (U_Y + 16 + (6 * Y_F) - (6 * Y_F2) - (G_S \ 2))
    Set C_X2 (U_X + 16 - (6 * X_F) + (6 * X_F2) - (G_S \ 2))
    Set C_Y2 (U_Y + 16 - (6 * Y_F) + (6 * Y_F2) - (G_S \ 2))
  Else
    Set C_X (U_X + 16 + (6 * X_F) + (6 * X_F2) - (G_S \ 2))
    Set C_Y (U_Y + 16 + (6 * Y_F) + (6 * Y_F2) - (G_S \ 2))
    Set C_X2 (U_X + 16 - (6 * X_F) - (6 * X_F2) - (G_S \ 2))
    Set C_Y2 (U_Y + 16 - (6 * Y_F) - (6 * Y_F2) - (G_S \ 2))
  EndIf

EndIf
PlaySound Swing.wav
Set L_N -4
Wait Start
For i = 1 To 6
  ClearPicture
  PaintPicture WP_FILE (C_X + (X_F * L_N)) ((C_Y + (Y_F * L_N)) + (6 - i)) G_S G_S 透過 DRCT 右回転 (ANG + i * 60) T_COL_F
  If (W_FLG = 1) Then
    PaintPicture WP_FILE (C_X2 + (X_F * L_N)) ((C_Y2 + (Y_F * L_N)) + (6 - i)) G_S G_S 透過 DRCT 右回転 (ANG + i * 60) T_COL_F
  EndIf
  Refresh
  Wait Until (i * 0.3)
Next
_SelectSound "Reload.wav" _GetWavFromArgs()
Wait Start
For i = 1 To 3
  Switch i
  Case 1
    Set L_N -4
  Case 2
    Set L_N 2
  Case 3
    Set L_N 0
  EndSw
  ClearPicture
  PaintPicture WP_FILE (C_X + (X_F * L_N)) (C_Y + (Y_F * L_N)) G_S G_S 透過 DRCT 右回転 ANG T_COL_F
  If (W_FLG = 1) Then
    PaintPicture WP_FILE (C_X2 + (X_F * L_N)) (C_Y2 + (Y_F * L_N)) G_S G_S 透過 DRCT 右回転 ANG T_COL_F
  EndIf
  Refresh
  Wait Until (i * 0.6)
Next

Wait Until 7

Return "Keep"

##################################################

戦闘アニメ_３点バースト攻撃:
UpVar

Local UID = _GetName(対象ユニットＩＤ,_GetIDFromArgs())
_UnSetBattleAnimeValue

Local BMP_FILE = _SelectWPBN(マシンガン)
Local G_S = _SelectWPBS(マシンガン)
Local C_X =  WX(UID)
Local C_Y =  WY(UID)
Local W_X = (C_X + 16 - (G_S \ 2))
Local W_Y = (C_Y + 16 - (G_S \ 2))
Local ANG = _GetAngle(UID)
Local X_F = _GetCircumference(ANG,Ｘ)
Local Y_F = _GetCircumference(ANG,Ｙ)
Local DRCT = _FlipVertical(ANG)
Local LN = 2
Local i j r
Local T_COL1 = _ColorTime(1)
For r = 1 To 3
	For j = 1 To 3
		_SelectSound "Rifle.wav" _GetWavFromArgs()
		For i = 1 To 2
		ClearPicture
		Switch i
		Case 1
			Set LN 2
			Set T_TCOL T_COL_F
			PaintPicture BMP_FILE (W_X + (X_F * LN)) (W_Y + (Y_F * LN)) G_S G_S 透過 DRCT 右回転 ANG T_COL1
			PaintPicture "Attack\EFFECT_MuzzleFlashB01.bmp" (C_X + (X_F * G_S \ 2)) (C_Y + (Y_F * G_S \ 2)) 右回転 (ANG + 45) 透過 T_COL1
		Case 2
			Set LN -2
			Set T_TCOL T_COL1
			PaintPicture BMP_FILE (W_X + (X_F * LN)) (W_Y + (Y_F * LN)) G_S G_S 透過 DRCT 右回転 ANG T_COL1
		EndSw
		Refresh
		Wait 0.5
		Next
	Next
Playsound -.wav
ClearPicture
Set LN 2
PaintPicture BMP_FILE (W_X + (X_F * LN)) (W_Y + (Y_F * LN)) G_S G_S 透過 DRCT 右回転 ANG T_TCOL
Refresh
Wait 1
Next
ClearPicture
Refresh
Return

##################################################

戦闘アニメ_３点バースト命中:
Call 戦闘アニメ_マシンガン命中 _GetWavFromArgs() _GetIDFromArgs()
Return

##################################################