################################################################################################
##############################      閃光斬撃       #############################################
################################################################################################
#PolygonとLineを利用した、画面全体を使った斬撃
#細かく、角度を指定できるのが売りか 

戦闘アニメ_閃光斬撃準備:
Return

戦闘アニメ_閃光斬撃攻撃:
Call 戦闘アニメ_斬撃攻撃 ホワイト _GetWavFromArgs() _GetIDFromArgs()
Return

################################################################################################

#オプション 色 斬撃の方向(デフォルトランダム 指定可能 縦 横) 斬撃の位置(デフォルトランダム 数字指定(0〜480)) 効果音

戦闘アニメ_閃光斬撃命中:

Center 相手ユニット
Refresh

Local i
Local l_1
Local l_2
Local l_3
Local l_4
Local m
Local CR1
Local CG1
Local CB1
Local tor

_CenteringCheck 相手ユニットＩＤ
Set i_X WX(相手ユニットＩＤ)
Set i_Y WY(相手ユニットＩＤ)

Set CR1 250
Set CG1 250
Set CB1 250
Switch _GetColorFromArgs() 
Case "レッド" "赤" "赤色" "Red" "red" "RED" "Ｒｅｄ" "ｒｅｄ" "ＲＥＤ"
	Set CR1 250
	Set CG1 100
	Set CB1 100
Case "ブルー" "青" "青色" "Blue" "blue" "BLUE" "Ｂｌｕｅ" "ｂｌｕｅ" "ＢＬＵＥ"
	Set CR1 100
	Set CG1 100
	Set CB1 250
Case "イエロー" "黄" "黄色" "Yellow" "yellow" "YELLOW" "Ｙｅｌｌｏｗ" "ｙｅｌｌｏｗ" "ＹＥＬＬＯＷ"
	Set CR1 250
	Set CG1 250
	Set CB1 100
Case "グリーン" "緑" "緑色" "Green" "green" "GREEN" "Ｇｒｅｅｎ" "ｇｒｅｅｎ" "ＧＲＥＥＮ"
	Set CR1 100
	Set CG1 250
	Set CB1 100
Case "ピンク" "桃" "桃色" "Pink" "pink" "PINK" "Ｐｉｎｋ" "ｐｉｎｋ" "ＰＩＮＫ"
	Set CR1 250
	Set CG1 100
	Set CB1 200
Case "ブラック" "黒" "Black" "black" "BLACK" "Ｂｌａｃｋ" "ｂｌａｃｋ" "ＢＬＡＣＫ"
	Set CR1 100
	Set CG1 100
	Set CB1 100
Case "パープル" "紫" "紫色" "Purple" "purple" "PURPLE" "Ｐｕｒｐｌｅ" "ｐｕｒｐｌｅ" "ＰＵＲＰＬＥ"
	Set CR1 200
	Set CG1 100
	Set CB1 250
Case "ホワイト" "白" "白色" "White" "white" "WHITE" "Ｗｈｉｔｅ" "ｗｈｉｔｅ" "ＷＨＩＴＥ"
 	Set CR1 250
	Set CG1 250
	Set CB1 250
Case "オレンジ" "橙" "橙色" "だいだい" "だいだい色" "Orange" "orange" "ORANGE" "Ｏｒａｎｇｅ" "ｏｒａｎｇｅ" "ＯＲＡＮＧＥ"
	Set CR1 250
	Set CG1 150
	Set CB1 100
Case "ライトブルー" "水色" "Lightblue" "lightblue" "LIGHTBLUE" "Ｌｉｇｈｔｂｌｕｅ" "ｌｉｇｈｔｂｌｕｅ" "ＬＩＧＨＴＢＬＵＥ"
	Set CR1 100
	Set CG1 250
	Set CB1 250
EndSw

If Args(2) = "" Then
  set tor Random(2)
Else
　If Args(2) = ランダム Then
  set tor Random(2)
  EndIf
　If Args(2) = 横 Then
　set tor 1
  EndIf
　If Args(2) = 縦 Then
　set tor 2
  EndIf
EndIf

If Args(3) = "" Then
  set l_1 Random(480)
  set l_2 (480 - l_1)
  set l_3 0
  set l_4 480
Else
  set l_1 Args(3)
  set l_2 (480 - l_1)
  set l_3 0
  set l_4 480
EndIf

_SelectSound Slash.wav _GetWavFromArgs()

If tor = 1 Then
	For m = 0 To 10
		PaintPicture Info(ユニット,相手ユニットＩＤ,グラフィック) i_X ((i_Y - 2) + Random(4)) 32 32 透過
		Switch m
		Case 1 2 3 4 5
			Color RGB(CR1,CG1,CB1)
			FillStyle 塗りつぶし
			FillColor RGB(CR1,CG1,CB1)
			Polygon l_3 l_1  l_3 ((l_1 - 10) + (m * 2))  l_4 ((l_2 - 10) + (m * 2))  l_4 l_2  l_4 ((l_2 + 10) - (m * 2))  l_3 ((l_1 + 10) - (m * 2))
		Case 7 9
			Line l_3 l_1 l_4 l_2 RGB(CR1,CG1,CB1)
		EndSw
		Refresh
		Wait 0.1
		ClearPicture
	Next
Else
	For m = 0 To 10
		PaintPicture Info(ユニット,相手ユニットＩＤ,グラフィック) i_X ((i_Y - 2) + Random(4)) 32 32 透過
		Switch m
		Case 1 2 3 4 5
			Color RGB(CR1,CG1,CB1)
			FillStyle 塗りつぶし
			FillColor RGB(CR1,CG1,CB1)
			Polygon l_1 l_3  ((l_1 - 10) + (m * 2)) l_3  ((l_2 - 10) + (m * 2)) l_4  l_2 l_4  ((l_2 + 10) - (m * 2)) l_4  ((l_1 + 10) - (m * 2)) l_3
		Case 7 9
			Line l_1 l_3 l_2 l_4 RGB(CR1,CG1,CB1)
		EndSw
		Refresh
		Wait 0.1
		ClearPicture
	Next
EndIf
ClearPicture
Refresh
Return