##################################################################################
#_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/打ちつけ_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/__/_#
##################################################################################
#敵を捕らえて地面にガンガン打ちつける

#オプション 打ちつけ回数 速度(速 遅 指定しない場合中速) 効果音

戦闘アニメ_打ちつけ準備:
Return

戦闘アニメ_打ちつけ攻撃:
Call 戦闘アニメ_スーパータックル攻撃 _GetWavFromArgs() _GetIDFromArgs()
Return "Keep"

################################################################################################

戦闘アニメ_打ちつけ命中:

Local i j l a
Local BMP_FILE
Local BMP_FILE2
Local BMP_FILE3
Local BMP_FILE4
Local G_C = _GetName("(White)",_G_BC_FA())
Local B_A = _GetNumberFromArgs()
Local B_X
Local UID
Local ANG
Local C_X C_Y A_X A_Y
Local X_F
Local Y_F
Local T_K
Local T_COL1 = _ColorTime(1)
Local T_COL = _ColorTime()
Local DRCT = _FlipVertical(ANG)
Local DRCT2
Local T_SPD = _GetSpeedFromArgs()
Local W_T
Set UID _GetName(対象ユニットＩＤ,_GetIDFromArgs())
_CenteringCheck 相手ユニットＩＤ
Set C_X WX(相手ユニットＩＤ)
Set C_Y WY(相手ユニットＩＤ)
Set A_X WX(対象ユニットＩＤ)
Set A_Y WY(対象ユニットＩＤ)
Set BMP_FILE _GetBMPName(相手ユニットＩＤ)
Set BMP_FILE2 _GetTileName(相手ユニットＩＤ)
Set BMP_FILE3 _GetBMPName(対象ユニットＩＤ)
Set BMP_FILE4 _GetTileName(対象ユニットＩＤ)
Set ANG _GetAngle(UID)
Set X_F _GetCircumference(ANG,Ｘ)
Set Y_F _GetCircumference(ANG,Ｙ)

If B_A = "" Then
  Set B_A 3
EndIf

If (X(UID) >= _Get_X(相手ユニットＩＤ)) Then
  Set DRCT ""
  Set DRCT2 左回転
  Set B_X -16
Else
  Set DRCT 左右反転
  Set DRCT2 右回転
  Set B_X +16
EndIf

If (_SearchOptionFromArgs("遅") != "") Then
  Set W_T 0.5
ElseIf (_SearchOptionFromArgs("速") != "") Then
  Set W_T 0.1
Else
  Set W_T 0.3
EndIf

ChangeUnitBitmap UID 非表示
ChangeUnitBitmap 相手ユニットＩＤ 非表示

PlaySound Punch.wav
For i = 1 To 10
	ClearPicture
	_PaintTile BMP_FILE4 A_X A_Y
	_PaintTile BMP_FILE2 C_X C_Y
	PaintPicture BMP_FILE3 (C_X - (X_F * 10)) (C_Y - (Y_F * 10)) 透過
	Switch i
	Case 1 3 5 7 9
	PaintPicture BMP_FILE ((C_X + 2) - (X_F * (0 - 10))) (C_Y - (Y_F * (0 - 10))) 透過
	Case 2 4 6 8 10
	PaintPicture BMP_FILE ((C_X - 2) - (X_F * (0 - 10))) (C_Y - (Y_F * (0 - 10))) 透過
	EndSw
	PaintPicture ("Hit\EFFECT_DamageN0" & i & ".bmp") (C_X - 16) (C_Y - 16) 64 64 透過
	Refresh
	Wait 0.3
Next
For l = 1 To B_A
	PlaySound Swing.wav
	For i = 1 To 5
		ClearPicture
		_PaintTile BMP_FILE4 A_X A_Y
		_PaintTile BMP_FILE2 C_X C_Y
		PaintPicture BMP_FILE3 C_X C_Y 透過
		Switch i
		Case 1 3 5 7 9
		PaintPicture BMP_FILE ((C_X + 2) + B_X) C_Y 透過 DRCT DRCT2 90
		Case 2 4 6 8 10
		PaintPicture BMP_FILE ((C_X - 2) + B_X) C_Y 透過 DRCT DRCT2 90
		EndSw
		PaintPicture ("Attack\EFFECT_Swing0" & i & ".bmp") (C_X + B_X) C_Y 32 32 透過 DRCT 上下反転
		Refresh
		Wait W_T
	Next
	For i = 1 To 5
		ClearPicture
		_PaintTile BMP_FILE4 A_X A_Y
		_PaintTile BMP_FILE2 C_X C_Y
		PaintPicture BMP_FILE3 C_X C_Y 透過
		Switch i
		Case 1 3 5 7 9
		PaintPicture BMP_FILE ((C_X + 2) + (B_X / 2)) (C_Y - 16) 透過 DRCT DRCT2 45
		Case 2 4 6 8 10
		PaintPicture BMP_FILE ((C_X - 2) + (B_X / 2)) (C_Y - 16) 透過 DRCT DRCT2 45
		EndSw
		PaintPicture ("Attack\EFFECT_Swing0" & i & ".bmp") (C_X + B_X) (C_Y + 4) 32 32 透過 DRCT
		Refresh
		Wait W_T
	Next
	_SelectSound "Punch.wav" _GetWavFromArgs() 
	For i = 1 To 10
		ClearPicture
		_PaintTile BMP_FILE4 A_X A_Y
		_PaintTile BMP_FILE2 C_X C_Y
		Switch i
		Case 1 3 5 7 9
		PaintPicture BMP_FILE3 C_X C_Y 透過
		PaintPicture BMP_FILE ((C_X - 2) + (B_X / 2)) (C_Y + 16) 透過 DRCT DRCT2 135
		Case 2 4 6 8 10
		PaintPicture BMP_FILE3 C_X C_Y 透過
		PaintPicture BMP_FILE ((C_X + 2) + (B_X / 2)) (C_Y + 16) 透過 DRCT DRCT2 135
		EndSw
		PaintPicture ("Impact\EFFECT_GrandEffect" & G_C & "0" & i & ".bmp") ((C_X - 48) + (B_Y / 2)) (C_Y - 8) 128 64 透過
		Refresh
		Wait W_T
	Next
Next
ChangeUnitBitmap 対象ユニットＩＤ 非表示解除
ChangeUnitBitmap 相手ユニットＩＤ 非表示解除
ClearPicture
Refresh
Return